如何检查x86汇编中的密钥状态？
今年一月，我把x86汇编作为一项业余爱好，所以我可以制作适用于像PCj和Tandy 1000这样的老式8086电脑的游戏，但我发现的书并没有在这个特定主题上教授太多东西。 虽然有些dos和bios会打断他们的工作，但他们并不完美。
我的主要问题是在不停止程序的情况下读取所按键的键盘状态。 我发现了一些方法，但它们非常有限。 INT 21h，AH 0Ch读取上次按下的按键，但采用文本编辑的方式。 它不仅一次只能读取一个密钥，而且记事本般的命中检测功能使得不可能知道密钥持续了多长时间。 在我的Google旅行中，我也看到了端口60h到64h的引用，但仅此而已，引用。 实际的解释和工作代码实际上是不存在的。 或者，也许我在使用搜索引擎时表现不好。
我需要知道的是一把钥匙是否被扣下。 最好的解决方案是拥有所有键盘按键的缓冲区/数组并读取其状态; 1意味着关闭，0意味着不关闭。 或者只是有权访问最后一个键被列出并释放的列表会很好（当然有一种清除缓冲区的方法）。 任何人都可以将我指向正确的方向吗？
编辑：首先，我应该提到我使用Borland TASM。 现在我编译了你的代码，它工作的很好，尽管我几乎不敢承认我不明白其中的一半。 我试图使它与TASM兼容，但它所做的只是在屏幕上创建垃圾并冻结。
这是我想出来的;
.MODEL TINY
.STACK 256
.DATA
kbdbuf DB 128 DUP (0)
msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"
.CODE
main PROC
org 0100h
mov ax, @data
mov ds, ax
xor ax, ax
mov es, ax
cli ; update ISR address w/ ints disabled
push word [es:9*4+2] ; preserve ISR address
push word [es:9*4]
lea si, irq1isr
mov word [es:9*4], si ; requires a register
mov [es:9*4+2],cs
sti
mov ah, 9
lea dx, msg1
int 021h ; print "Press and hold ESC"
test1:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jz test1 ; wait until it's nonzero (pressed/held)
lea dx, msg2
int 021h ; print "ESC pressed, release ESC"
test2:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jnz test2 ; wait until it's zero (released/not pressed)
lea dx, msg3 ; print "ESC released"
int 021h
cli ; update ISR address w/ ints disabled
pop word [es:9*4] ; restore ISR address
pop word [es:9*4+2]
sti
ret
irq1isr:
push ax bx
; read keyboard scan code
in al, 060h
; update keyboard state
xor bh, bh
mov bl, al
and bl, 07Fh ; bx = scan code
shr al, 7 ; al = 0 if pressed, 1 if released
xor al, 1 ; al = 1 if pressed, 0 if released
mov [cs:bx+kbdbuf], al
; send EOI to XT keyboard
in al, 061h
mov ah, al
or al, 080h
out 061h, al
mov al, ah
out 061h, al
; send EOI to master PIC
mov al, 020h
out 020h, al
pop bx ax
iret
main ENDP
END main
我不确定我是否编写了中断的权利。 而且，如果我知道端口060h - 064h是如何工作的。
你可以这样做：
; compile with NASM: nasm.exe -f bin kbd.asm -o kbd.com
bits 16
org 0x100
xor ax, ax
mov es, ax
cli ; update ISR address w/ ints disabled
push word [es:9*4+2] ; preserve ISR address
push word [es:9*4]
mov word [es:9*4], irq1isr
mov [es:9*4+2],cs
sti
call test
cli ; update ISR address w/ ints disabled
pop word [es:9*4] ; restore ISR address
pop word [es:9*4+2]
sti
ret
test:
mov ah, 9
mov dx, msg1
int 0x21 ; print "Press and hold ESC"
test1:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jz test1 ; wait until it's nonzero (pressed/held)
mov dx, msg2
int 0x21 ; print "ESC pressed, release ESC"
test2:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jnz test2 ; wait until it's zero (released/not pressed)
mov dx, msg3 ; print "ESC released"
int 0x21
ret
irq1isr:
pusha
; read keyboard scan code
in al, 0x60
; update keyboard state
xor bh, bh
mov bl, al
and bl, 0x7F ; bx = scan code
shr al, 7 ; al = 0 if pressed, 1 if released
xor al, 1 ; al = 1 if pressed, 0 if released
mov [cs:bx+kbdbuf], al
; send EOI to XT keyboard
in al, 0x61
mov ah, al
or al, 0x80
out 0x61, al
mov al, ah
out 0x61, al
; send EOI to master PIC
mov al, 0x20
out 0x20, al
popa
iret
kbdbuf:
times 128 db 0
msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"
在DOS / Win9x / NT / 2K / XP / 32位Vista / 7或DosBox中运行。
更新： TASM版本：
; file: kbdt.asm
; compile with TASM/TLINK:
; tasm.exe kbdt.asm
; tlink.exe /t kbdt.obj
.286
code segment use16
assume cs:code, ds:code, ss:code
org 100h
main:
xor ax, ax
mov es, ax
cli ; update ISR address w/ ints disabled
push word ptr es:[9*4+2] ; preserve ISR address
push word ptr es:[9*4]
mov word ptr es:[9*4], offset irq1isr
mov es:[9*4+2],cs
sti
call test0
cli ; update ISR address w/ ints disabled
pop word ptr es:[9*4] ; restore ISR address
pop word ptr es:[9*4+2]
sti
ret
test0:
mov ah, 9
mov dx, offset msg1
int 21h ; print "Press and hold ESC"
test1:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jz test1 ; wait until it's nonzero (pressed/held)
mov dx, offset msg2
int 21h ; print "ESC pressed, release ESC"
test2:
mov al, [kbdbuf + 1] ; check Escape key state (Esc scan code = 1)
or al, al
jnz test2 ; wait until it's zero (released/not pressed)
mov dx, offset msg3 ; print "ESC released"
int 21h
ret
irq1isr:
pusha
; read keyboard scan code
in al, 60h
; update keyboard state
xor bh, bh
mov bl, al
and bl, 7Fh ; bx = scan code
shr al, 7 ; al = 0 if pressed, 1 if released
xor al, 1 ; al = 1 if pressed, 0 if released
mov cs:[bx+kbdbuf], al
; send EOI to XT keyboard
in al, 61h
mov ah, al
or al, 80h
out 61h, al
mov al, ah
out 61h, al
; send EOI to master PIC
mov al, 20h
out 20h, al
popa
iret
kbdbuf db 128 dup (0)
msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"
code ends
end main
通常，对于像这样的旧系统，人们使用BIOS有点像预先提供的一组库函数，其中像键盘功能之类的东西只有在方便时才使用。 在你的情况下，BIOS键盘服务不方便，所以你不要使用它们。
相反，您想用自己的键盘中断处理程序替换BIOS键盘中断处理程序，并实现您自己的键盘驱动程序。 键盘使用IRQ1，即中断9.中断向量表从0x0000开始：0x0000，因此您希望在0x0000：9 * 4 = 0x0000：0x0024处获得4个字节并将它们存储在某处（以便您可以将它们放回原处在你的软件退出时保持正常），并将你自己的键盘IRQ处理程序的地址（偏移然后段）放到那里。
要编写自己的键盘驱动程序，您首先需要了解涉及2个硬件。 计算机中的键盘控制器芯片（或“PS / 2控制器”）通过键盘本身与芯片通信（通过串行通信）。
有关键盘控制器芯片的信息，请参阅http://wiki.osdev.org/%228042%22_PS/2_Controller
有关键盘内部芯片的信息，请参阅http://wiki.osdev.org/PS/2_Keyboard
使用端口60h和端口64h轮询键盘的示例：
cli ; stop software-Interrupts
mov al, 2 ; stop IRQ 1
out 21h, al
sti
P1:
in al, 64h ; get Status
test al, 1 ; is there something in the outputbuffer?
jz P1
test al, 20h ; it is a byte from the PS2-Mouse?
jnz P1
in al, 60h ; get a key
cmp al, 1 ; Escape-key?
jz XRAUS ; then goto end
;───────────────────────────────────────────────────────────────
mov si, OFFSET SONTAB ; get the offsetaddress of our special-key table
mov cl, Extablen ; lenght
XSUCH: cmp al, [si]
jz XFOUND
lea si, [si+1] ; instead of "inc si"
dec cl
jnz XSUCH
;───────────────────────────────────────────────────────────────
mov si, OFFSET TASTTAB ; get the offsetaddress of our key table
mov cx, tablen
mov bx, OFFSET TEXTTAB ; our corresponding ASCII table
SUCH: cmp al, [si]
jz short FOUND
lea si, [si+1]
dec cx
jnz SUCH
jmp P1
;───────────────────────────────────────────────────────────────
XRAUS: in al, 60h ; clear outputbuffer
cli
xor al, al ; enable IRQ 1
out 21h, al
sti
mov ah, 1 ; clear buffer in the ram
int 16h
; ...some more instructions
;───────────────────────────────────────────────────────────────
FOUND: mov si, tablen ; Length
sub si, cx
xor ecx, ecx
mov cl, [bx+si] ; get the ASCII from our table
; ...some more instructions
;───────────────────────────────────────────────────────────────
XFOUND:
; Tab,shift li.,shift re.,HOME,UP,LEFT,RIGHT,END,DOWN
cmp cl, 1 ; DOWN-key
jnz short ... ; jump to next
....
....
cmp cl, 9 ; Tab-key
jnz P1
; ...some more instructions
:------------------------Data area----------------------
TASTTAB DB 02h,03h,04h,05h,06h,07h,08h,09h,0Ah,0Bh,0Ch,0Dh
DB 10h,11h,12h,13h,14h,15h,16h,17h,18h,19h,1Ah,1Bh,1Eh,1Fh
DB 20h,21h,22h,23h,24h,25h,26h,27h,28h,29h,2Bh,2Ch,2Dh,2Eh,2Fh
DB 30h,31h,32h,33h,34h,35h,39h
DB 56h
tablen = ($-TASTTAB)
TEXTTAB DB "1234567890ß'" ; with some german letters inside
DB "qwertzuiopü+as"
DB "dfghjklöä^#yxcv"
DB "bnm,.- "
DB "<"
Textablen = ($-TEXTTAB)
;---------------------------------------------------------------------------
; Tab,shift left.,shift rigth.,HOME,UP,LEFT,RIGHT,END,DOWN
;----------
SONTAB DB 0Fh,2Ah,36h,47h,48h,4Bh,4Dh,4Fh,50h
Extablen = ($-SONTAB)
DB 0,0,0 ; for data_alignment of following entries