在结构上使用“新”是否将它分配到堆或栈上？

当你用new操作符创建一个类的实例时，内存将被分配到堆上。 当你使用new运算符创建一个结构实例时，内存分配的位置，堆或堆栈上？

---

好吧，让我们看看我能否做得更清楚。

首先，Ash是正确的：问题不在于分配值类型变量的位置。 这是一个不同的问题 - 答案不仅仅是“在堆叠上”。 它比这更复杂（并且由C＃2变得更加复杂）。 我有一篇关于这个话题的文章，如果需要的话，将会扩展它，但是我们只处理new运营商。

其次，这一切都取决于你在谈论什么水平。 我正在研究编译器对源代码所做的事情，就它创建的IL而言。 JIT编译器在优化相当多的“逻辑”分配方面会做很多巧妙的事情。

第三，我忽略了泛型，主要是因为我实际上并不知道答案，部分原因是它会让事情变得复杂。

最后，所有这些都与当前的实施一致。 C＃规范没有详细说明 - 它实际上是一个实现细节。 有些人认为托管代码开发人员真的不应该在意。 我不确定我会走多远，但值得一想的是，一个实际上所有局部变量都在堆上的世界 - 这仍然符合规范。

---

new运算符在值类型上有两种不同的情况：可以调用无参数构造函数（例如new Guid() ）或有参数的构造函数（例如new Guid(someString) ）。 这些产生显着不同的IL。 要理解为什么，您需要比较C＃和CLI规范：根据C＃，所有值类型都有一个无参数构造函数。 根据CLI规范，没有值类型具有无参数的构造函数。 （一段时间用反射获取值类型的构造函数 - 你不会找到无参数的。）

对于C＃来说，将“用零初始化一个值”作为构造函数是有道理的，因为它保持了语言的一致性 - 您可以将new(...)视为始终调用构造函数。 CLI有不同的想法是有道理的，因为没有真正的代码可以调用 - 当然也没有类型特定的代码。

在初始化它之后，您将如何处理该值也会产生影响。 IL用于

Guid localVariable = new Guid(someString);

与用于以下情况的IL不同：

myInstanceOrStaticVariable = new Guid(someString);

另外，如果该值用作中间值，例如方法调用的参数，则事情会再次略有不同。 为了显示所有这些差异，这里有一个简短的测试程序。 它没有显示静态变量和实例变量之间的差异：IL会在stfld和stsfld之间不同，但仅此stsfld 。

using System;

public class Test
{
    static Guid field;

    static void Main() {}
    static void MethodTakingGuid(Guid guid) {}


    static void ParameterisedCtorAssignToField()
    {
        field = new Guid("");
    }

    static void ParameterisedCtorAssignToLocal()
    {
        Guid local = new Guid("");
        // Force the value to be used
        local.ToString();
    }

    static void ParameterisedCtorCallMethod()
    {
        MethodTakingGuid(new Guid(""));
    }

    static void ParameterlessCtorAssignToField()
    {
        field = new Guid();
    }

    static void ParameterlessCtorAssignToLocal()
    {
        Guid local = new Guid();
        // Force the value to be used
        local.ToString();
    }

    static void ParameterlessCtorCallMethod()
    {
        MethodTakingGuid(new Guid());
    }
}

以下是该类的IL，不包括不相关的位（如nops）：

.class public auto ansi beforefieldinit Test extends [mscorlib]System.Object    
{
    // Removed Test's constructor, Main, and MethodTakingGuid.

    .method private hidebysig static void ParameterisedCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: stsfld valuetype [mscorlib]System.Guid Test::field
        L_0010: ret     
    }

    .method private hidebysig static void ParameterisedCtorAssignToLocal() cil managed
    {
        .maxstack 2
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid    
        L_0003: ldstr ""    
        L_0008: call instance void [mscorlib]System.Guid::.ctor(string)    
        // Removed ToString() call
        L_001c: ret
    }

    .method private hidebysig static void ParameterisedCtorCallMethod() cil  managed    
    {   
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0011: ret     
    }

    .method private hidebysig static void ParameterlessCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldsflda valuetype [mscorlib]System.Guid Test::field
        L_0006: initobj [mscorlib]System.Guid
        L_000c: ret 
    }

    .method private hidebysig static void ParameterlessCtorAssignToLocal() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        // Removed ToString() call
        L_0017: ret 
    }

    .method private hidebysig static void ParameterlessCtorCallMethod() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        L_0009: ldloc.0 
        L_000a: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0010: ret 
    }

    .field private static valuetype [mscorlib]System.Guid field
}

正如你所看到的，有很多不同的指令用于调用构造函数：

newobj ：分配堆栈中的值，调用参数化的构造函数。 用于中间值，例如用于赋值给字段或用作方法参数。

call instance ：使用已经分配的存储位置（无论是否在堆栈上）。 这在上面的代码中用于分配给局部变量。 如果同一个局部变量多次使用几次new调用赋值，它只是初始化旧值顶部的数据 - 它不会每次分配更多的堆栈空间。

initobj ：使用已分配的存储位置并擦除数据。 这用于我们所有的无参数构造函数调用，包括那些分配给局部变量的构造函数。 对于方法调用，有效地引入了一个中间局部变量，其值由initobj 。

我希望这可以说明这个话题是多么复杂，同时也让我们看到了一些亮点。 在某些概念意义上，每一次new分配都会在堆栈中分配空间 - 但正如我们所看到的，即使在IL级别也不是真正发生的事情。 我想强调一个特例。 采取这种方法：

void HowManyStackAllocations()
{
    Guid guid = new Guid();
    // [...] Use guid
    guid = new Guid(someBytes);
    // [...] Use guid
    guid = new Guid(someString);
    // [...] Use guid
}

这个“逻辑上”有4个堆栈分配 - 一个用于变量，另一个用于三个new调用 - 但实际上（对于该特定代码）堆栈只分配一次，然后重用相同的存储位置。

编辑：只是要清楚，这只是在某些情况下是真的...特别是，如果Guid构造函数抛出异常， guid的值将不可见，这就是为什么C＃编译器能够重用相同的堆栈插槽。 有关更多详细信息以及不适用的情况，请参阅Eric Lippert关于价值类型构建的博文。

我在写这个答案的过程中学到了很多，如果有任何不清楚的地方，请澄清一下！

---

包含struct字段的内存可以根据具体情况分配在堆栈或堆上。 如果struct-type变量是某个匿名委托或迭代器类未捕获的局部变量或参数，则它将被分配到堆栈上。 如果变量是某个类的一部分，那么它将在堆中的类中分配。

如果结构被分配在堆上，那么调用new运算符实际上并不是分配内存所必需的。 唯一的目的是根据构造函数中的内容设置字段值。 如果构造函数没有被调用，那么所有的字段将得到它们的默认值（0或null）。

同样，对于在堆栈中分配的结构，除了C＃要求所有局部变量在使用前都设置为某个值之外，因此您必须调用自定义构造函数或默认构造函数（不带参数的构造函数始终可用于结构）。

---

简而言之，新结构对于结构体来说是错误的，称新结构体只是简单地称之为构造函数。 结构的唯一存储位置是它所定义的位置。

如果它是一个成员变量，它将直接存储在其中定义的任何变量中，如果它是一个局部变量或参数，则它将存储在堆栈中。

将它与类进行对比，该类在结构完全存储的任何地方都有引用，而参考点位于堆的某处。 （成员内，本地/参数堆栈）

它可能有助于查看C ++中的哪些类/结构之间没有真正的区别。 （在语言中有类似的名字，但它们只是指事物的默认可访问性）当你调用new时，你得到一个指向堆位置的指针，而如果你有一个非指针引用，它直接存储在堆栈中，或者在另一个对象中，C＃中的ala结构。

链接地址: http://www.djcxy.com/p/14529.html

上一篇: Does using "new" on a struct allocate it on the heap or stack?

下一篇: Does this type of memory get allocated on the heap or the stack?