检测（在VBA中）何时包含excel实例的窗口变为活动状态
当我在Excel中切换窗口时，我可以看到WindowActivate事件在不同级别触发，但是有什么办法在excel成为前台应用程序时触发事件？ 如果我点击excel并开始工作，例如在浏览器中工作一段时间，然后再点击回到excel窗口，我看不到任何事件发生。 有什么方法可以检测到这个？
我想刷新我的VBA应用程序的一些元素，因为偶尔我发现基于超文本函数的鼠标移动功能失去了激活图表的能力。 我可以通过取消保护和保护工作表，或者通过重新初始化我的对象的子集来修复它。 我想在我正在寻找的事件上触发此操作。
我也可以通过SendKeys来做到这一点，但它并不好，因为由于SendKeys中存在一个已记录的错误，它会消除键盘设置（例如滚动锁定），并且使屏幕闪烁的次数超过了我的意愿。
由于代码将驻留在VBA中，因此我会将操作限制在特定的工作簿中。 如果在进入Excel实例窗口时不同的（被动）工作簿处于活动状态，则不会触发任何操作，并且如果用户选择包含该工作簿的工作簿，则可以使用WorkbookActivate事件刷新应用程序。
我相信这不是直接在Excel中提供的，所以使用Windows API。 你可以在VBA中做win32编程！
说明
您可以使用win32 api函数SetWinEventHook让Windows向您报告某些事件。 包括在前景窗口更改时触发的EVENT_SYSTEM_FOREGROUND。 在下面的例子中，我根据Excel的进程ID检查新的前台窗口的进程ID。 这是一种简单的方法，但它会检测其他Excel窗口，例如VBA窗口与主Excel窗口相同。 这可能是也可能不是你想要的行为，可以相应地改变。
您必须小心使用SetWinEventHook，因为您将回调函数传递给它。 你在这个回调函数中的作用是有限的，它存在于VBA的正常执行之外，它内部的任何错误都会导致Excel以不可恢复的混乱方式崩溃。
这就是为什么我使用Application.OnTime来报告事件。 如果多个事件触发得比Excel和VBA更新更快，它们不会保证顺序发生。 但它更安全。 您也可以更新一个集合或事件数组，然后单独在WinEventFunc回调之外单独读取它们。
示例代码
为了测试这个，创建一个新模块并将其粘贴到它中。 然后运行StartHook。 记住在关闭Excel或修改代码之前运行StopAllEventHooks！ 在生产代码中，您可能会将StartEventHook和StopAllEventHooks添加到WorkBook_Open和WorkBook_BeforeClose事件中，以确保它们在适当的时间运行。 请记住，如果在挂钩停止之前发生WinEventFunc VBA代码， Excel将崩溃 。 这包括正在修改的代码或它被关闭时的工作簿。 也不要按在VBA停止按钮，而钩处于活动状态。 停止按钮可以擦除当前程序状态！
Option Explicit
Private Const EVENT_SYSTEM_FOREGROUND = &H3&
Private Const WINEVENT_OUTOFCONTEXT = 0
Private Declare Function SetWinEventHook Lib "user32.dll" (ByVal eventMin As Long, ByVal eventMax As Long, _
ByVal hmodWinEventProc As Long, ByVal pfnWinEventProc As Long, ByVal idProcess As Long, _
ByVal idThread As Long, ByVal dwFlags As Long) As Long
Private Declare Function GetCurrentProcessId Lib "kernel32" () As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hWnd As Long, lpdwProcessId As Long) As Long
Private pRunningHandles As Collection
Public Function StartEventHook() As Long
If pRunningHandles Is Nothing Then Set pRunningHandles = New Collection
StartEventHook = SetWinEventHook(EVENT_SYSTEM_FOREGROUND, EVENT_SYSTEM_FOREGROUND, 0&, AddressOf WinEventFunc, 0, 0, WINEVENT_OUTOFCONTEXT)
pRunningHandles.Add StartEventHook
End Function
Public Sub StopEventHook(lHook As Long)
Dim LRet As Long
If lHook = 0 Then Exit Sub
LRet = UnhookWinEvent(lHook)
End Sub
Public Sub StartHook()
StartEventHook
End Sub
Public Sub StopAllEventHooks()
Dim vHook As Variant, lHook As Long
For Each vHook In pRunningHandles
lHook = vHook
StopEventHook lHook
Next vHook
End Sub
Public Function WinEventFunc(ByVal HookHandle As Long, ByVal LEvent As Long, _
ByVal hWnd As Long, ByVal idObject As Long, ByVal idChild As Long, _
ByVal idEventThread As Long, ByVal dwmsEventTime As Long) As Long
'This function is a callback passed to the win32 api
'We CANNOT throw an error or break. Bad things will happen.
On Error Resume Next
Dim thePID As Long
If LEvent = EVENT_SYSTEM_FOREGROUND Then
GetWindowThreadProcessId hWnd, thePID
If thePID = GetCurrentProcessId Then
Application.OnTime Now, "Event_GotFocus"
Else
Application.OnTime Now, "Event_LostFocus"
End If
End If
On Error GoTo 0
End Function
Public Sub Event_GotFocus()
Sheet1.[A1] = "Got Focus"
End Sub
Public Sub Event_LostFocus()
Sheet1.[A1] = "Nope"
End Sub
这里有一个想法如何实现使用VBA：检测Excel何时失去焦点？
链接地址: http://www.djcxy.com/p/17693.html上一篇: Detecting (in VBA) when the window containing an excel instance becomes active