是否可以在VirtualStringTree中多次显示一个对象？
我意识到我真的需要重写我的程序数据结构（不是现在，但很快，因为截止日期是星期一），因为我目前使用VST（VirtualStringTree）来存储我的数据。
我想实现的是联系人列表结构。 根节点是类别，孩子是联系人。 共有2个级别。
但事情是，我需要一个联系人来显示多个类别，但他们需要同步。 特别是Checkstate 。
目前，为了保持同步，我循环遍历整个树，以找到具有与刚刚更改的ID相同的ID的节点。 但是当有大量的节点时，这样做非常缓慢。
所以，我想：可以在多个类别中显示联系人对象的一个实例吗？
注意：老实说，我并不是100％熟悉术语 - 我的意思是Instance，它是一个对象（或记录），所以我不必通过整个树来查找具有相同ID的Contact对象。
这里是一个例子：
如您所见，Todd Hirsch出现在“测试类别”和“所有联系人”中。 但在幕后，这些是2个PVirtualNodes ，所以当我更改某个节点的某个属性（如CheckState）或节点的Data Record / Class中的某个属性时，2个节点不同步。 目前我可以同步它们的唯一方法是循环播放我的树，找到所有容纳同一联系人的节点，并将更改应用到它们及其数据。
总结一下：我正在寻找的是一种使用一个对象/记录的方法，并在我的树中以多个类别显示它 - 每当检查一个节点时，每个其他节点都包含相同的Contact对象。
我在这里有什么意义吗？
当然可以。 你需要在脑海中分离节点和数据。 TVirtualStringTree中的节点不需要保存数据，可以简单地用于指向可以找到数据的实例。 当然，您可以将两个节点指向同一个对象实例。
假设你有一个TPerson列表，并且你有一棵树，你想在不同的节点上显示每个人。 然后，您将您用于节点的记录简单地声明为：
TNodeRecord = record
... // anything else you may need or want
DataObject: TObject;
...
end;
在初始化节点的代码中，您可以执行如下操作：
PNodeRecord.DataObject := PersonList[SomeIndex];
这是它的要点。 如果你想要一个通用的NodeRecord，就像我上面展示的那样，那么你需要将它转换回适当的类，以便在各种Get ...方法中使用它。 您当然也可以为每个树创建一个特定的记录，您将DataObject声明为您在树中显示的特定类型的类。 唯一的缺点是，你然后限制树显示该类对象的信息。
我应该有一个更详细的例子躺在某处。 当我找到它时，我会将它添加到这个答案中。
例
声明树要使用的记录：
RTreeData = record
CDO: TCustomDomainObject;
end;
PTreeData = ^RTreeData;
TCustomDomainObject是我所有域信息的基类。 它被宣布为：
TCustomDomainObject = class(TObject)
private
FList: TObjectList;
protected
function GetDisplayString: string; virtual;
function GetCount: Cardinal;
function GetCDO(aIdx: Cardinal): TCustomDomainObject;
public
constructor Create; overload;
destructor Destroy; override;
function Add(aCDO: TCustomDomainObject): TCustomDomainObject;
property DisplayString: string read GetDisplayString;
property Count: Cardinal read GetCount;
property CDO[aIdx: Cardinal]: TCustomDomainObject read GetCDO;
end;
请注意，该类设置为可以保存其他TCustomDomainObject实例的列表。 在显示你的树的表单上添加：
TForm1 = class(TForm)
...
private
FIsLoading: Boolean;
FCDO: TCustomDomainObject;
protected
procedure ShowColumnHeaders;
procedure ShowDomainObject(aCDO, aParent: TCustomDomainObject);
procedure ShowDomainObjects(aCDO, aParent: TCustomDomainObject);
procedure AddColumnHeaders(aColumns: TVirtualTreeColumns); virtual;
function GetColumnText(aCDO: TCustomDomainObject; aColumn: TColumnIndex;
var aCellText: string): Boolean;
protected
property CDO: TCustomDomainObject read FCDO write FCDO;
public
procedure Load(aCDO: TCustomDomainObject);
...
end;
Load方法是所有开始的地方：
procedure TForm1.Load(aCDO: TCustomDomainObject);
begin
FIsLoading := True;
VirtualStringTree1.BeginUpdate;
try
if Assigned(CDO) then begin
VirtualStringTree1.Header.Columns.Clear;
VirtualStringTree1.Clear;
end;
CDO := aCDO;
if Assigned(CDO) then begin
ShowColumnHeaders;
ShowDomainObjects(CDO, nil);
end;
finally
VirtualStringTree1.EndUpdate;
FIsLoading := False;
end;
end;
它所做的只是清除表单并为新的CustomDomainObject进行设置，在大多数情况下，它将是包含其他CustomDomainObjects的列表。
ShowColumnHeaders方法设置字符串树的列标题，并根据列数调整标题选项：
procedure TForm1.ShowColumnHeaders;
begin
AddColumnHeaders(VirtualStringTree1.Header.Columns);
if VirtualStringTree1.Header.Columns.Count > 0 then begin
VirtualStringTree1.Header.Options := VirtualStringTree1.Header.Options
+ [hoVisible];
end;
end;
procedure TForm1.AddColumnHeaders(aColumns: TVirtualTreeColumns);
var
Col: TVirtualTreeColumn;
begin
Col := aColumns.Add;
Col.Text := 'Breed(Group)';
Col.Width := 200;
Col := aColumns.Add;
Col.Text := 'Average Age';
Col.Width := 100;
Col.Alignment := taRightJustify;
Col := aColumns.Add;
Col.Text := 'CDO.Count';
Col.Width := 100;
Col.Alignment := taRightJustify;
end;
AddColumnHeaders被分离出来以允许这个表单被用作其他表单在树中显示信息的基础。
ShowDomainObjects看起来像整个树将被加载的方法。 事实并非如此。 毕竟，我们正在处理一个虚拟树。 所以我们需要做的就是告诉虚拟树我们有多少个节点：
procedure TForm1.ShowDomainObjects(aCDO, aParent: TCustomDomainObject);
begin
if Assigned(aCDO) then begin
VirtualStringTree1.RootNodeCount := aCDO.Count;
end else begin
VirtualStringTree1.RootNodeCount := 0;
end;
end;
我们现在大部分都已经设置好了，只需要实现各种VirtualStringTree事件就可以完成所有事情。 第一个要实现的事件是OnGetText事件：
procedure TForm1.VirtualStringTree1GetText(Sender: TBaseVirtualTree; Node:
PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText:
string);
var
NodeData: ^RTreeData;
begin
NodeData := Sender.GetNodeData(Node);
if GetColumnText(NodeData.CDO, Column, {var}CellText) then
else begin
if Assigned(NodeData.CDO) then begin
case Column of
-1, 0: CellText := NodeData.CDO.DisplayString;
end;
end;
end;
end;
它从VirtualStringTree获取NodeData并使用获得的CustomDomainObject实例获取其文本。 它使用GetColumnText函数来完成这个工作，并且再次完成这个工作，以允许使用此表单作为显示树的其他表单的基础。 当你走这条路线时，你会声明这个方法是虚拟的，并以任何后代形式覆盖它。 在这个例子中，它被简单地实现为：
function TForm1.GetColumnText(aCDO: TCustomDomainObject; aColumn: TColumnIndex;
var aCellText: string): Boolean;
begin
if Assigned(aCDO) then begin
case aColumn of
-1, 0: begin
aCellText := aCDO.DisplayString;
end;
1: begin
if aCDO.InheritsFrom(TDogBreed) then begin
aCellText := IntToStr(TDogBreed(aCDO).AverageAge);
end;
end;
2: begin
aCellText := IntToStr(aCDO.Count);
end;
else
// aCellText := '';
end;
Result := True;
end else begin
Result := False;
end;
end;
既然我们已经告诉VirtualStringTree如何从节点记录中使用CustomDomainObject实例，我们当然仍然需要将主CDO中的实例链接到树中的节点。 这是在OnInitNode事件中完成的：
procedure TForm1.VirtualStringTree1InitNode(Sender: TBaseVirtualTree;
ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
var
ParentNodeData: ^RTreeData;
ParentNodeCDO: TCustomDomainObject;
NodeData: ^RTreeData;
begin
if Assigned(ParentNode) then begin
ParentNodeData := VirtualStringTree1.GetNodeData(ParentNode);
ParentNodeCDO := ParentNodeData.CDO;
end else begin
ParentNodeCDO := CDO;
end;
NodeData := VirtualStringTree1.GetNodeData(Node);
if Assigned(NodeData.CDO) then begin
// CDO was already set, for example when added through AddDomainObject.
end else begin
if Assigned(ParentNodeCDO) then begin
if ParentNodeCDO.Count > Node.Index then begin
NodeData.CDO := ParentNodeCDO.CDO[Node.Index];
if NodeData.CDO.Count > 0 then begin
InitialStates := InitialStates + [ivsHasChildren];
end;
end;
end;
end;
Sender.CheckState[Node] := csUncheckedNormal;
end;
由于我们的CustomDomainObject可以包含其他CustomDomainObjects的列表，因此当lsit的Count大于零时，我们还将该节点的InitialStates设置为包含HasChildren。 这意味着我们还需要实现OnInitChildren事件，当用户单击树中的加号时会调用该事件。 同样，我们需要做的就是告诉树需要准备多少个节点：
procedure TForm1.VirtualStringTree1InitChildren(Sender: TBaseVirtualTree; Node:
PVirtualNode; var ChildCount: Cardinal);
var
NodeData: ^RTreeData;
begin
ChildCount := 0;
NodeData := Sender.GetNodeData(Node);
if Assigned(NodeData.CDO) then begin
ChildCount := NodeData.CDO.Count;
end;
end;
这就是所有人！
正如我用一个简单的列表显示了一个例子， 您仍然需要找出哪些数据实例需要链接到哪些节点，但是您现在应该有一个公平的想法，即您需要这样做的地方：您设置的OnInitNode事件节点记录的CDO成员指向您选择的CDO实例。
链接地址: http://www.djcxy.com/p/35023.html上一篇: Is it possible to display one object multiple times in a VirtualStringTree?