Shortest command to calculate the sum of a column of output on Unix?
I'm sure there is a quick and easy way to calculate the sum of a column of values on Unix systems (using something like awk or xargs perhaps), but writing a shell script to parse the rows line by line is the only thing that comes to mind at the moment.
For example, what's the simplest way to modify the command below to compute and display the total for the SEGSZ column (70300)?
ipcs -mb | head -6
IPC status from /dev/kmem as of Mon Nov 17 08:58:17 2008
T ID KEY MODE OWNER GROUP SEGSZ
Shared Memory:
m 0 0x411c322e --rw-rw-rw- root root 348
m 1 0x4e0c0002 --rw-rw-rw- root root 61760
m 2 0x412013f5 --rw-rw-rw- root root 8192
ipcs -mb | tail +4 | awk '{ sum += $7 } END { print sum }'
Or without tail:
ipcs -mb | awk 'NR > 3 { sum += $7 } END { print sum }'
Using awk with bc to have arbitrary long results (credits to Jouni K. ):
ipcs -mb | awk 'NR > 3 { print $7 }' | paste -sd+ | bc
I would try to construct a calculation string and feed it to bc as follows:
ipcs -mb | grep -w '^m ' | sed 's/^.*s//' | xargs | tr ' ' + | bc
Looks like this is slightly longer than the awk solution, but for everyone who can't read (and understand) the odd awk code this may be easier to grasp... :-)
If bc is not installed you can use double parentheses in step 5 above to calculate the result:
echo $(( $(ipcs -mb | grep -w '^m ' | sed 's/^.*s//' | xargs | tr ' ' +) )) or SUM=$(( $(ipcs -mb | grep -w '^m ' | sed 's/^.*s//' | xargs | tr ' ' +) )) or (( SUM=$(ipcs -mb | grep -w '^m ' | sed 's/^.*s//' | xargs | tr ' ' +) )) The spacing after and before the double parentheses is optional.
I have a utility script which simply adds up all columns. It's usually easy enough to grab the one you want from the one-line output. As a bonus, some SI-suffixes are recognized.
#!/usr/bin/awk -f
# Sum up numerical values by column (white-space separated)
#
# Usage: $0 [file ...]
#
# stern, 1999-2005
{
for(i = 1; i <= NF; ++i) {
scale = 1
if ($i ~ /[kK]$/) { scale = 1000 }
if ($i ~ /[mM]$/) { scale = 1000*1000 }
if ($i ~ /[gG]$/) { scale = 1000*1000*1000 }
col[i] += scale * $i;
}
if (NF > maxnf) maxnf = NF;
}
END {
for(i = 1; i <= maxnf; ++i) { printf " %.10g", col[i] }
print "";
}
Example with custom field separator:
$ head /etc/passwd | addcol -F:
0 0 45 39 0 0 0
上一篇: 是否有可能在C＃7.0中重载解构器？