使用Delphi XE7和Indy类创建亚马逊MWS签名
我需要为亚马逊MWS生成签名，并决定只使用Delphi提供的组件和类来找到解决方案。 因为我使用Indy作为自己的HTTP帖子，所以使用Indy类来计算RFC 2104兼容的HMAC似乎是个好主意。
对于那些从事亚马逊集成工作的人来说，在“亚马逊教程”中很好地解释了“规范化查询字符串”的创建过程：http://docs.developer.amazonservices.com/en_DE/dev_guide/DG_ClientLibraries.html要小心，只是使用＃10进行换行，因为＃13＃10或＃13将失败并出现错误的签名。 如问题＃23573799所述，根据TIdHttp版本添加“：443”到亚马逊端点（主机）也很重要。
要创建一个有效的签名，我们必须使用SHA256计算一个HMAC，并使用查询字符串和我们在注册后从亚马逊获得的SecretKey，然后结果必须在BASE64中进行编码。
查询字符串已正确生成，并与亚马逊Scratchpad创建的字符串相同。 但由于签名不正确，通话失败。
经过一些测试后，我意识到从我的查询字符串中得到的签名与我在使用PHP生成时得到的结果不一样。 PHP的结果被认为是正确的，因为我的PHP解决方案很长一段时间与亚马逊一起工作，德尔菲的结果是不同的，这是不正确的。
为了使测试更容易，我使用'1234567890'作为查询字符串的值，'ABCDEFG'作为SecretKey的替换值。 当我使用Delphi获得的结果与使用PHP获得的结果相同时，我相信问题应该得到解决。
这里是我如何用PHP获得正确的结果：
echo base64_encode(hash_hmac('sha256', '1234567890', 'ABCDEFG', TRUE));
这显示了结果
aRGlc3RY1pKmKX0hvorkVKNcPigiJX2rksqXzlAeCLg=
下面的Delphi XE7代码返回错误的结果，同时使用Delphi XE7附带的indy版本：
uses
IdHash, IdHashSHA, IdHMACSHA1, IdSSLOpenSSL, IdGlobal, IdCoderMIME;
function GenerateSignature(const AData, AKey: string): string;
var
AHMAC: TIdBytes;
begin
IdSSLOpenSSL.LoadOpenSSLLibrary;
With TIdHMACSHA256.Create do
try
Key:= ToBytes(AKey, IndyTextEncoding_UTF16LE);
AHMAC:= HashValue(ToBytes(AData, IndyTextEncoding_UTF16LE));
Result:= TIdEncoderMIME.EncodeBytes(AHMAC);
finally
Free;
end;
end;
这里的结果显示在备忘录中
Memo.Lines.Text:= GenerateSignature('1234567890', 'ABCDEFG');
是：
jg6Oddxvv57fFdcCPXrqGWB9YD5rSvtmGnZWL0X+y0Y=
我相信这个问题与编码有关，所以我对此做了一些研究。 正如亚马逊教程（链接参见上文）所述，亚马逊期望采用utf8编码。
由于Indy函数“ToBytes”需要一个字符串，在我的Delphi版本中是一个UnicodeString字符串，所以我放弃使用其他字符串类型作为参数或变量的UTF8String进行测试，但我不知道utf8应该到达哪里。 此外，我不知道我在上面的代码中使用的编码是否正确。 我选择UTF16LE是因为UnicodeString是utf16编码（详情请参见http://docwiki.embarcadero.com/RADStudio/Seattle/en/String_Types_(Delphi）），LE（Little-Endian）是现代机器上最常用的。 德尔福的TEncodings本身也有“Unicode”和“BigEndianUnicode”，所以“Unicode”似乎是LE和某种“标准”的Unicode。 当然，我在上面的代码中测试了使用IndyTextEncoding_UTF8而不是IndyTextEncoding_UTF16LE，但它无法工作。
因为
TIdEncoderMIME.EncodeBytes(AHMAC);
首先将TidBytes写入Stream，然后用8bit编码读取它，这也可能是问题的根源，所以我还测试了
Result:= BytesToString(AHMAC, IndyTextEncoding_UTF16LE);
Result:= TIdEncoderMIME.EncodeString(Result, IndyTextEncoding_UTF16LE);
但结果是一样的。
如果你想看看创建请求的主要代码，这里是：
function TgboAmazon.MwsRequest(const AFolder, AVersion: string;
const AParams: TStringList; const AEndPoint: string): string;
var
i: Integer;
SL: TStringList;
AMethod, AHost, AURI, ARequest, AStrToSign, APath, ASignature: string;
AKey, AValue, AQuery: string;
AHTTP: TIdHTTP;
AStream, AResultStream: TStringStream;
begin
AMethod:= 'POST';
AHost:= AEndPoint;
AURI:= '/' + AFolder + '/' + AVersion;
AQuery:= '';
SL:= TStringList.Create;
try
SL.Assign(AParams);
SL.Values['AWSAccessKeyId']:= FAWSAccessKeyId;
SL.Values['SellerId']:= FSellerId;
FOR i:=0 TO FMarketplaceIds.Count-1 DO
begin
SL.Values['MarketplaceId.Id.' + IntToStr(i+1)]:= FMarketplaceIds[i];
end;
SL.Values['Timestamp']:= GenerateTimeStamp(Now);
SL.Values['SignatureMethod']:= 'HmacSHA256';
SL.Values['SignatureVersion']:= '2';
SL.Values['Version']:= AVersion;
FOR i:=0 TO SL.Count-1 DO
begin
AKey:= UrlEncode(SL.Names[i]);
AValue:= UrlEncode(SL.ValueFromIndex[i]);
SL[i]:= AKey + '=' + AValue;
end;
SortList(SL);
SL.Delimiter:= '&';
AQuery:= SL.DelimitedText;
AStrToSign:= AMethod + #10 + AHost + #10 + AURI + #10 + AQuery;
TgboUtil.ShowMessage(AStrToSign);
ASignature:= GenerateSignature(AStrToSign, FAWSSecretKey);
TgboUtil.ShowMessage(ASignature);
APath:= 'https://' + AHost + AURI + '?' + AQuery + '&Signature=' + Urlencode(ASignature);
TgboUtil.ShowMessage(APath);
finally
SL.Free;
end;
AHTTP:= TIdHTTP.Create(nil);
try
AHTTP.IOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(AHTTP);
AHTTP.Request.ContentType:= 'text/xml';
AHTTP.Request.Connection:= 'Close';
AHTTP.Request.CustomHeaders.Add('x-amazon-user-agent: MyApp/1.0 (Language=Delphi/XE7)');
AHTTP.HTTPOptions:= AHTTP.HTTPOptions + [hoKeepOrigProtocol];
AHTTP.ProtocolVersion:= pv1_0;
AStream:= TStringStream.Create;
AResultStream:= TStringStream.Create;
try
AHTTP.Post(APath, AStream, AResultStream);
Result:= AResultStream.DataString;
ShowMessage(Result);
finally
AStream.Free;
AResultStream.Free;
end;
finally
AHTTP.Free;
end;
end;
Urlencode和GenerateTimestamp是我自己的函数，它们按照名称承诺做什么，SortList是我自己的过程，它按照亚马逊的要求按字节顺序对字符串列表进行排序，TgboUtil.ShowMessage是我自己的ShowMessage替代方法，它显示包含所有字符的完整消息，仅用于调试。 http协议仅用于测试，因为我得到了403（拒绝的权限），因为HTTP返回的时间较早。 我只是想排除这个问题，因为indy文档说，协议版本1.1被认为是不完整的，因为有问题的服务器答案。
这里有几个关于amazon mws主题的帖子，但是这个具体问题似乎是新的。
这里的这个问题可能会帮助那些刚到达目前为止还没有来过的人，同时也希望有人能够提供一个解决方案，以便像在PHP中一样获得与Delphi相同的签名值。
先谢谢你。
使用Indy 10的最新SVN快照，我无法重现您的签名问题。 在使用UTF-8时，您的示例键+值数据在Delphi中与PHP输出中产生相同的结果。 所以，你的GenerateSignature()函数很好，只要：
您使用IndyTextEncoding_UTF8而不是IndyTextEncoding_UTF16LE 。
你要确保AData和AKey包含有效的输入数据。
此外，您应该确保TIdHashSHA256.IsAvailable返回true，否则TIdHashHMACSHA256.HashValue()将失败。 例如，如果OpenSSL加载失败，可能会发生这种情况。
试试这个：
function GenerateSignature(const AData, AKey: string): string;
var
AHMAC: TIdBytes;
begin
IdSSLOpenSSL.LoadOpenSSLLibrary;
if not TIdHashSHA256.IsAvailable then
raise Exception.Create('SHA-256 hashing is not available!');
with TIdHMACSHA256.Create do
try
Key := IndyTextEncoding_UTF8.GetBytes(AKey);
AHMAC := HashValue(IndyTextEncoding_UTF8.GetBytes(AData));
finally
Free;
end;
Result := TIdEncoderMIME.EncodeBytes(AHMAC);
end;
这就是说，你的MwsRequest()函数有很多问题：
您正在泄漏TIdSSLIOHandlerSocketOpenSSL对象。 您没有为其分配Owner ，并且TIdHTTP在分配给其IOHandler属性时并不拥有所有权。 实际上，在您的示例中分配IOHanlder实际上是可选的，请参阅针对TIdHTTP的新HTTPS功能。
您正在将AHTTP.Request.ContentType设置为错误的媒体类型。 您没有发送XML数据，因此不要将媒体类型设置为'text/xml' 。 在这种情况下，您需要将其设置为'application/x-www-form-urlencoded' 。
当调用AHTTP.Post() ，你的AStream流是空的，所以你实际上并没有发送任何数据到服务器。 您正在将您的AQuery数据放入URL本身的查询字符串中，但它实际上属于AStream 。 如果要发送URL查询字符串中的数据，则必须使用TIdHTTP.Get()而不是TIdHTTP.Post() ，并将AMethod值更改为'GET'而不是'POST' 。
您正在使用填充输出TStream的TIdHTTP.Post()版本。 您正在使用TStringStream将响应转换为String而不考虑响应数据使用的实际字符集。 由于您没有在TStringStream构造函数中指定任何TEncoding对象，因此它将使用TEncoding.Default进行解码，这可能不会（也可能不会）匹配响应的实际字符集。 您应该使用返回String的Post()的其他版本，以便TIdHTTP可以根据HTTPS服务器报告的实际字符集解码响应数据。
而不是尝试更像这样的东西：
function TgboAmazon.MwsRequest(const AFolder, AVersion: string;
const AParams: TStringList; const AEndPoint: string): string;
var
i: Integer;
SL: TStringList;
AMethod, AHost, AURI, AQuery, AStrToSign, APath, ASignature: string;
AHTTP: TIdHTTP;
begin
AMethod := 'POST';
AHost := AEndPoint;
AURI := '/' + AFolder + '/' + AVersion;
AQuery := '';
SL := TStringList.Create;
try
SL.Assign(AParams);
SL.Values['AWSAccessKeyId'] := FAWSAccessKeyId;
SL.Values['SellerId'] := FSellerId;
for i := 0 to FMarketplaceIds.Count-1 do
begin
SL.Values['MarketplaceId.Id.' + IntToStr(i+1)] := FMarketplaceIds[i];
end;
SL.Values['Timestamp'] := GenerateTimeStamp(Now);
SL.Values['SignatureMethod'] := 'HmacSHA256';
SL.Values['SignatureVersion'] := '2';
SL.Values['Version'] := AVersion;
SL.Values['Signature'] := '';
SortList(SL);
for i := 0 to SL.Count-1 do
SL[i] := UrlEncode(SL.Names[i]) + '=' + UrlEncode(SL.ValueFromIndex[i]);
SL.Delimiter := '&';
SL.QuoteChar := #0;
SL.StrictDelimiter := True;
AQuery := SL.DelimitedText;
finally
SL.Free;
end;
AStrToSign := AMethod + #10 + Lowercase(AHost) + #10 + AURI + #10 + AQuery;
TgboUtil.ShowMessage(AStrToSign);
ASignature := GenerateSignature(AStrToSign, FAWSSecretKey);
TgboUtil.ShowMessage(ASignature);
APath := 'https://' + AHost + AURI;
TgboUtil.ShowMessage(APath);
AHTTP := TIdHTTP.Create(nil);
try
// this is actually optional in this example...
AHTTP.IOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(AHTTP);
AHTTP.Request.ContentType := 'application/x-www-form-urlencoded';
AHTTP.Request.Connection := 'close';
AHTTP.Request.UserAgent := 'MyApp/1.0 (Language=Delphi/XE7)';
AHTTP.Request.CustomHeaders.Values['x-amazon-user-agent'] := 'MyApp/1.0 (Language=Delphi/XE7)';
AHTTP.HTTPOptions := AHTTP.HTTPOptions + [hoKeepOrigProtocol];
AHTTP.ProtocolVersion := pv1_0;
AStream := TStringStream.Create(AQuery + '&Signature=' + Urlencode(ASignature);
try
Result := AHTTP.Post(APath, AStream);
ShowMessage(Result);
finally
AStream.Free;
end;
finally
AHTTP.Free;
end;
end;
然而，由于响应记录为XML，这将是更好地返回给调用者的响应TStream （不使用TStringStream ，虽然）或TBytes ，而不是作为一个String 。 这样，而不是Indy解码字节，让你的XML解析器自己解码原始字节。 XML有自己的独立于HTTP的字符集规则，所以让XML解析器为您完成工作：
procedure TgboAmazon.MwsRequest(...; Response: TStream);
var
...
begin
...
AHTTP.Post(APath, AStream, Response);
...
end;
上一篇: Creating an amazon MWS signature with Delphi XE7 and Indy classes