引导加载程序奇怪的行为
我一直在试图设计一个简单的操作系统，只是引导扇区，以及带有中断的16位实模式。 我终于可以制作出OS / bootloader，我在虚拟盒子里测试过了，它工作正常。
然后我把这张图像刻录到一张CD上，然后将它引导到我的旧桌面上，使用Pentium 4，BIOS修订版A05和1GB内存，并且它非常完美 - 一个简单的操作系统，可以将“标题”屏幕，所有它可以让你输入到屏幕上，并且注册几个键来浏览光标。
然后，我把光盘插入我的1年前的笔记本电脑，配有一个i5处理器和2.6 GB的RAM以及A05 BIOS修订版，光标似乎随机移动，高速打印随机字符，最后停在anscii字符处235（扩展字符表的一部分），此时键盘工作正常，用于移动光标的键可以正常工作，只是标题。 这是我测试过的电脑，进行了整理，写下来，并烧录了CD。 （我使用Linux Mint 12 OS）
我已经跳过了所有我认为需要做的“箍”：制作了一张符合El Torito'非仿真'引导标准，引导签名，512字节并写入正确扇区的ISO映像。
这是我的代码问题吗，我没有做过什么，或者这只是正常吗？
这是我的代码（NASM x86语法）：
;**************************
; Note OS, Experimental OS
;**************************
[org 0x7C00]
[bits 16]
start:
jmp loader ;jump to the actual start of bootloader
times 8 - ($ - $$) db 0 ;pad eight bytes
;*********************
;El Torito Boot Info Table
;*********************
;in nasm, I couldn't figure out how to reserve bytes, in the middle of .text
;so I zeroed it out.
times 56 db 0
loader:
call cls ;clear the screen
mov si, head1 ;setup page headers
call printf
mov si, head2
call printf
jmp note ;start note program
cls:
mov ah, 0x0F ;get current video mode
mov al, 0x00 ;reset register
int 0x10 ;get video mode
mov ah, 0x00 ;set video mode
int 0x10 ;reset screen
mov ah, 0x02 ;set cursor pos
mov bh, 0x00 ;page 00
mov dh, 0x00 ;row 00
mov dl, 0x00 ;col. 00
int 0x10 ;set pos
ret
printf:
.loop ;our function that loops
mov al, [si] ;load byte
cmp al, 0 ;if null, end
je .end
mov ah, 0x0E ;function 0E
mov bh, 0x00 ;page 0x00
mov bl, 0x0F ;white text on black background
int 0x10 ;print
inc si ;increment source index
jmp .loop ;repeat
.end
ret ;return
;*******************
; Note 'Program'
;*******************
note:
mov ah, 0x00 ;function 00
int 0x16 ;get character
cmp al, '`' ;go up line?
je setcur
cmp al, 0x0D ;enter?
je setent
cmp al, '+' ;plus?
je setplu
cmp al, '-' ;minus?
je setminu
cmp al, '' ;reset?
je loader
cmp al, 0x08 ;backspace?
je setback
mov ah, 0x0E ;function 0E
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10 ;print
jmp note ;repeat
setcur:
mov ah, 0x03 ;get cur pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
cmp dh, 0x00 ;are we at top of page?
je .begin ;just reset cursor if so
sub dh, 0x01 ;go up one line
.begin
mov dl, 0x00 ;set to beginning of line
mov ah, 0x02 ;set cursor function
mov bh, 0x00 ;page 00
int 0x10 ;set position
jmp note ;read next character
setent:
mov ah, 0x0E ;write character
mov al, 0x0A ;begin line
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10 ;print
setplu:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 0x00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
add dl, 0x01 ;add one to column
int 0x10 ;set new pos
jmp note ;get next char
setminu:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
sub dl, 0x01 ;sub one to column
int 0x10 ;set new pos
jmp note ;get next char
setback:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
sub dl, 0x01 ;sub one column
int 0x10 ;set pos
mov ah, 0x0E ;write char
mov al, ' ' ;write space
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10
mov ah, 0x02 ;reset cur pos
int 0x10 ;reset
jmp note
;******************
; Our Page Headers
;******************
head1: db '- Note OS Version 1.2-', 0x0A, 0x0D, 0
head2: db '=======================', 0x0A, 0x0D, 0x0A, 0x0D, 0
times 510 - ($ - $$) db 0
dw 0xAA55
对于参考（我引用的东西）：
Anscii表格：http：//www.asciitable.com/
El-Torito信息：http://wiki.osdev.org/El-Torito
编辑：这里是我编程的键和他们做什么：
输入 - 正常工作现在退格 - 现在正常工作加上 - 将光标向右移动减去 - 向左移动光标` - 将光标移动到上一行的开始“”软重启“几乎跳转到加载器的开始
问题在这里：
[org 0x7C00]
...
start:
jmp loader ;jump to the actual start of bootloader
...
loader:
call cls ;clear the screen
mov si, head1 ;setup page headers
call printf
...
printf:
.loop ;our function that loops
mov al, [si] ;load byte
当你的代码开始时，你期望CS=DS=0 。 DS不能保证为0.所以，当它不为零时， mov al, [si]会从段0以外的某个段读取字节，并且可能会有一些垃圾，而不是您的问候消息的副本。
另外，有些BIOS会使用0:0x7C00的地址跳转到您的代码，而另一些则使用0x7C0:0 ，这意味着即使CS不保证具有固定值。
我会做的是这样的：
[org 0x7C00]
[bits 16]
start:
jmp loader ;jump to the actual start of bootloader
...
loader:
jmp 0:loader2 ; this far jump guarantees CS=0
loader2:
push cs
pop ds ; this guarantees DS=0
; the rest of the code goes here
Wowsers; 现在这是一个很重要的问题！
实际上，在Stack Overflow上真正起作用的编程问题太笼统了，但仅仅是为了向你挑选一些东西，希望能有所帮助！
如果你已经到了甚至可以随意移动光标的地步，尽管是随机的，那么我猜你的引导程序是可以的; 但要清楚 - 它甚至会在I5上显示“标题”？
我在这里看到的是中断矢量/地址线/等，你用它来使光标四处移动。 你确定int10操作是完全通用的吗？
链接地址: http://www.djcxy.com/p/58223.html