如何配置FastMM来检测DLL中的内存泄漏

我无法弄清楚如何检测静态或甚至动态链接的DLL中的内存泄漏。 我只是想检测DLL中的泄漏，我不想在DLL和应用程序之间共享内存管理器。 此外，该DLL与运行时包相关联

我的示例DLL看起来像这样：

library dll;
uses
  fastmm4,
  System.SysUtils,
  System.Classes;
{$R *.res}
procedure MyInit; stdcall;
Begin
  TObject.Create;
End;
exports MyInit;
begin
end.

应用程序dpr：

program app;

uses
  //fastmm4,
  Vcl.Forms,
  main in 'main.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

注意：如果我取消fastmm4的注释，比我可以检测由应用程序（TStringList.Create）引起的memleak，而不是dll中的泄漏。

并且在应用程序主单元中：

unit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    LDLLHandle: HModule;
    LShowProc: TProcedure;
  end;

var
  Form1: TForm1;

{$ifdef static}
procedure MyInit; stdcall; external 'dll.dll';
{$endif}

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringList.Create;
  {$ifdef static}
  MyInit;
  {$else}
  LDLLHandle := LoadLibrary('dll.dll');
  if LDLLHandle <> 0 then
  begin
    try
      LShowProc := GetProcAddress(LDLLHandle, 'MyInit');
      if Assigned(LShowProc) then
        LShowProc;
    finally
      FreeLibrary(LDLLHandle);
    end;
  end;
  {$endif}
end;

end.

我希望FastMM能够在FreeLibrary被调用时或程序退出时生成一个报告，如果dll是静态加载的，但没有任何反应。

在FastMM4Options.inc我还额外设置了FullDebugMode和ClearLogFileOnStartup ，并且FastMM_FullDebugMode.dll位于输出目录中。

我在github上创建了一个仓库。 我错过了什么？

---

您的DLL不报告泄漏的原因源于FastMM关闭中的此代码：

  CheckBlocksOnShutdown(
  {$ifdef EnableMemoryLeakReporting}
        True
    {$ifdef RequireIDEPresenceForLeakReporting}
        and DelphiIsRunning
    {$endif}
    {$ifdef RequireDebuggerPresenceForLeakReporting}
        and ((DebugHook <> 0)
        {$ifdef PatchBCBTerminate}
        or (Assigned(pCppDebugHook) and (pCppDebugHook^ <> 0))
        {$endif PatchBCBTerminate}
        )
    {$endif}
    {$ifdef ManualLeakReportingControl}
        and ReportMemoryLeaksOnShutdown
    {$endif}
  {$else}
        False
  {$endif}
  );

在你的选项中， RequireDebuggerPresenceForLeakReporting被定义。 更重要的是，在DLL中， DebugHook等于0 ，可能是因为你正在调试应用程序而不是DLL。 这意味着你调用CheckBlocksOnShutdown传递False 。 而这个False会禁用泄漏报告。

您可以通过取消定义RequireDebuggerPresenceForLeakReporting来解决此RequireDebuggerPresenceForLeakReporting 。

---

我只是在Delphi2010上使用Fast Memory Manager 4.97进行测试 - win7

FastMM4是.dpr（project和dll）的'uses'子句中的第一个单元，

'ShareMM'选项已启用

“AttemptToUseSharedMM”选项已启用

'EnableMemoryLeakReporting'选项已启用

在exe文件夹中添加FastMM_FullDebugMode.dll

还有一个测试演示'动态加载的DLL'这个演示没有ShareMem。 我必须启用选项'ShareMM'和'AttemptToUseSharedMM'，并添加FastMM_FullDebugMode.dll以获得FastMM的泄漏报告。

链接地址: http://www.djcxy.com/p/72639.html

上一篇: How to configure FastMM to detect memory leak in a dll

下一篇: Evaluate() in VBA